Dalam dokumen seperti Invoice kadang kita perlu konsisten dalam penggunaan bahasa, jangan sampai dokumennya dalam bahasa Indonesia tetapi tanggal yang dicantumkan dalam bahasa Inggris.

Berikut ini function dalam Access VBA untuk menampilkan tanggal dalam bahasa Indonesia, tidak terpengaruh oleh setting bahasa atau format tanggal pada komputer.

Function fTanggalIndo(ByVal pTanggal As Variant, Optional ByVal pSingkat As Boolean = False) As String
    If IsNull(pTanggal) Then Exit Function
    '
    Dim tNamaBulan As Variant
    Dim tBulan As Integer
    Dim tNamaBulanPilihan As String

    ' Daftar nama bulan lengkap dalam bahasa Indonesia
    tNamaBulan = Array("Januari", "Februari", "Maret", "April", "Mei", "Juni", _
                       "Juli", "Agustus", "September", "Oktober", "November", "Desember")
                       
    ' Mendapatkan nomor bulan dari tanggal yang diberikan
    tBulan = Month(pTanggal)
    
    ' Tentukan nama bulan berdasarkan parameter pSingkat
    If pSingkat Then
        tNamaBulanPilihan = Left(tNamaBulan(tBulan - 1), 3)
    Else
        tNamaBulanPilihan = tNamaBulan(tBulan - 1)
    End If
    
    ' Membentuk format tanggal
    fTanggalIndo = Day(pTanggal) & " " & tNamaBulanPilihan & " " & Year(pTanggal)
End Function

Cara Pemakaian:

1. Copy-paste code di atas ke dalam sebuah general module (modul VBA umum yang bisa dibuat melalui ribbon CREATE > Module).
2. Gunakan ekspresi seperti contoh berikut ini untuk mendapatkan teks tanggal dalam bahasa Indonesia:
   tTanggal = fTanggalIndo(Tgl_Invoice)
   hasilnya (misal): 3 Maret 2025
3. Jika anda ingin nama bulan disingkat (3 huruf depan), gunakan ekspresi seperti contoh berikut ini:
   tTanggal = fTanggalIndo(Tgl_Invoice, True)
   hasilnya (misal): 3 Mar 2025

Semoga bermanfaat.